EmacsとVtermとREPLの改善

;; -*- lexical-binding: t; -*-

;; Copyright (C) TakesxiSximada
;;
;; Author: TakesxiSximada
;; Package-Requires: ((vterm))

;; This file is not part of GNU Emacs.

;; This file is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:
;;
;; This is REPL Utility for me.

;;; Code:

(require 'vterm)

(defvar my/repl-current-buffer nil
  "This is the buffer where the REPL is running. Code will be sent to this buffer.")

;;;###autoload
(defun my/repl-select-buffer (buf)
  "Set the selected buffer as the current buffer where the REPL is running."
  (interactive "bBuffer: ")
  (setq my/repl-current-buffer buf))

;;;###autoload
(defun my/repl-send-region-to-buffer-process (beg end)
  "Send the selected region's text to the current REPL buffer."
  (interactive "r")
  (let ((code (buffer-substring-no-properties beg end)))
    (with-current-buffer my/repl-current-buffer
      ;; Send the selected region's text to the current REPL buffer, assuming vterm.
      (vterm-insert code)
      (vterm-send-return)
      (vterm-send-return))))

;;;###autoload
(defun my/repl-send-buffer-to-buffer-process ()
  "Send the entire contents of the current buffer to the REPL buffer."
  (interactive)
  (my/repl-send-region-to-buffer-process (point-min)
					 (point-max)))

(defun my/repl-pre-check-before-send (&rest args)
  "Ensure `my/repl-current-buffer` is valid before sending."
  (unless (and my/repl-current-buffer
               (buffer-live-p (get-buffer my/repl-current-buffer)))
    (call-interactively 'my/repl-select-buffer)))

(advice-add 'my/repl-send-region-to-buffer-process :before #'my/repl-pre-check-before-send)
;; delete all hooks
;; (advice-mapc 'my/repl-send-buffer-to-buffer-process #'advice-remove)

;;;###autoload
(defun my/repl-send-line-to-buffer-process ()
  "Send the current line to the REPL buffer."
  (interactive)
  (my/repl-send-region-to-buffer-process (line-beginning-position)
					 (line-end-position)))

;;;
;;; Container Utility
;;;

(defvar my/repl-docker-executable "docker"
  "Docker command")

(defvar my/repl-docker-image-list nil
  "A list of container images used to start as a REPL.")

(defun my/repl-refresh-docker-image-list ()
  "Refresh the list of container images used to start as a REPL."
  (interactive)
  (setq my/repl-docker-image-list
	(string-split
	 (shell-command-to-string "docker image list --format '{{ .Repository }}:{{ .Tag }}'"))))

;;;
;;; REPL Launch Utility
;;;

(defun my/repl-launch-with-vterm-docker-run-pre-check (&rest args)
  "Update the list of Docker images as needed before starting a container for REPL with Docker."
  (unless my/repl-docker-image-list
    (call-interactively 'my/repl-refresh-docker-image-list)))

;;;###autoload
(defun my/repl-launch-with-vterm-docker-run (&optional image cmd workdir dotenv custom-args)
  "Start a REPL process using Docker with vterm."
  (interactive
   (list
    (completing-read "Image: " my/repl-docker-image-list)
    (read-shell-command "Cmd: ")
    (read-directory-name "Dir: " default-directory nil default-directory)
    (when (yes-or-no-p "Use dotenv?:")
      (read-file-name "Dotenv: " nil ".env" t))
    (when (yes-or-no-p "Use custom args?:")
      (read-file-name "Args file: " nil ".args" t))))

  (let* ((params-env-file (if dotenv (format " --env-file %s " (shell-quote-argument dotenv)) ""))
	 (params-custom-args (if custom-args
				 (string-trim
				  (shell-command-to-string (format "head -n 1 %s" custom-args))) ""))
	 (vterm-kill-buffer-on-exit nil)
	 (vterm-buffer-name (format "*%s*: %s" image workdir))
	 (vterm-shell
	  (format "%s run -i -t --volume %s:%s --workdir %s %s %s %s %s"
		  (shell-quote-argument my/repl-docker-executable)
		  (shell-quote-argument workdir)
		  (shell-quote-argument workdir)
		  (shell-quote-argument workdir)
		  (if (string-empty-p params-env-file) "" params-env-file)
		  (if (string-empty-p params-custom-args) "" (shell-quote-argument params-custom-args))
		  (shell-quote-argument image)
		  (if (string-empty-p cmd) "" (shell-quote-argument cmd)))))
    (message "[my/repl] launti container: %s" vterm-shell)
    (vterm)))

(advice-add 'my/repl-launch-with-vterm-docker-run :before #'my/repl-launch-with-vterm-docker-run-pre-check)

(provide 'my/repl)
;;; my.el ends here